graphql-language-service-cli: init at 3.5.0

Previously packaged by `node2nix`, removed in 776868c

Author: nathanregner

pkgs/by-name/gr/graphql-language-service-cli/esbuild.js

@@ -0,0 +1,49 @@
+// derived from graphql-vscode/esbuild.js
+const { build } = require('esbuild');
+
+build({
+  entryPoints: ['bin/graphql.js'],
+  bundle: true,
+  minify: true,
+  sourcemap: false,
+  platform: 'node',
+  outdir: 'out/',
+  external: [
+    'pnpapi',
+    // Avoid bundling @vue/compiler-sfc's dynamic dependencies
+    'squirrelly',
+    'teacup',
+    'coffee-script',
+    'marko',
+    'slm',
+    'vash',
+    'plates',
+    'babel-core',
+    'htmling',
+    'ractive',
+    'mote',
+    'eco',
+    'jqtpl',
+    'hamljs',
+    'jazz',
+    'hamlet',
+    'whiskers',
+    'haml-coffee',
+    'hogan.js',
+    'templayed',
+    'walrus',
+    'mustache',
+    'just',
+    'ect',
+    'toffee',
+    'twing',
+    'dot',
+    'bracket-template',
+    'vscode',
+    'velocityjs',
+    'dustjs-linkedin',
+    'atpl',
+    'liquor',
+    'twig',
+  ],
+});

pkgs/by-name/gr/graphql-language-service-cli/package.nix

@@ -0,0 +1,75 @@
+{
+  lib,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  makeWrapper,
+  nodejs,
+  stdenv,
+  yarnBuildHook,
+  yarnConfigHook,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "graphql-language-service-cli";
+  version = "3.5.0";
+
+  src = fetchFromGitHub {
+    owner = "graphql";
+    repo = "graphiql";
+    tag = "graphql-language-service-cli@${finalAttrs.version}";
+    hash = "sha256-NJTggaMNMjOP5oN+gHxFTwEdNipPNzTFfA6f975HDgM=";
+  };
+
+  yarnOfflineCache = fetchYarnDeps {
+    yarnLock = "${finalAttrs.src}/yarn.lock";
+    hash = "sha256-ae6KP2sFgw8/8YaTJSPscBlVQ5/bzbvHRZygcMgFAlU=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    nodejs
+    makeWrapper
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{bin,lib}
+
+    pushd packages/graphql-language-service-cli
+
+    # even with dev dependencies stripped, node_modules is over 1GB
+    # just bundle what we need
+    cp ${./esbuild.js} esbuild.js
+    node esbuild.js
+
+    # copy package.json for --version command
+    mv {out/graphql.js,package.json} $out/lib
+
+    makeWrapper ${nodejs}/bin/node $out/bin/graphql-lsp \
+      --add-flags $out/lib/graphql.js \
+
+    popd
+
+    runHook postInstall
+  '';
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  doInstallCheck = true;
+  versionCheckProgram = "${placeholder "out"}/bin/${finalAttrs.meta.mainProgram}";
+
+  passthru = {
+    updateScript = ./updater.sh;
+  };
+
+  meta = {
+    description = "Official, runtime independent Language Service for GraphQL";
+    homepage = "https://github.com/graphql/graphiql";
+    changelog = "https://github.com/graphql/graphiql/blob/${finalAttrs.src.tag}/packages/graphql-language-service-cli/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ nathanregner ];
+    mainProgram = "graphql-lsp";
+  };
+})

pkgs/by-name/gr/graphql-language-service-cli/updater.sh

@@ -0,0 +1,22 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p coreutils curl jq nix-update
+
+set -euo pipefail
+
+# this package is part of a monorepo with many tags; nix-update only seems to
+# fetch the 10 most recent
+# https://github.com/Mic92/nix-update/issues/231
+owner="graphql"
+repo="graphiql"
+version=$(
+    curl -s "https://api.github.com/repos/graphql/graphiql/git/refs/tags/graphql-language-service-cli" |
+        jq 'map(.ref | capture("refs/tags/graphql-language-service-cli@(?<version>[0-9.]+)").version) | .[]' -r |
+        sort --reverse --version-sort | head -n1
+)
+
+if [[ "$UPDATE_NIX_OLD_VERSION" == "$version" ]]; then
+    echo "Already up to date!"
+    exit 0
+fi
+
+nix-update graphql-language-service-cli --version $version