Add keccak and secp256k1 (#103)

Author: janmasrovira

Anoma/Builtin/ByteArray.juvix

@@ -34,6 +34,8 @@ module ByteArray;
   builtin anoma-bytearray-to-anoma-contents
   axiom rawToAnomaContents : ByteArray -> Nat;
 
+  toNat : ByteArray -> Nat := toAnomaContents >> AnomaAtom.toNat;
+
   toAnomaContents : ByteArray -> AnomaAtom :=
     rawToAnomaContents >> AnomaAtom.fromNat;
 

Applib.juvix

@@ -17,3 +17,5 @@ import Applib.Helpers open public;
 import Applib.Identities open public;
 import Applib.Authorization as Authorization public;
 import Applib.Trait.Tx open public;
+import Applib.Keccak256 open public;
+import Applib.Secp256k1 open public;

Applib/Keccak256.juvix

@@ -0,0 +1,17 @@
+module Applib.Keccak256;
+
+import Stdlib.Prelude open;
+import Anoma.Builtin.ByteArray open;
+import BaseLayer.AnomaAtom open;
+
+module Keccak;
+  hash : Nat -> ByteArray :=
+    Private.primKeccak >> AnomaAtom.fromNat >> ByteArray.fromAnomaContents size;
+
+  size : Nat := 32;
+
+  module Private;
+    builtin keccak256
+    axiom primKeccak : Nat -> Nat;
+  end;
+end;

Applib/Secp256k1.juvix

@@ -0,0 +1,115 @@
+module Applib.Secp256k1;
+
+import Stdlib.Prelude open;
+import Anoma.Builtin.ByteArray open;
+import BaseLayer.AnomaAtom open;
+import Anoma.Primitives.FixedSize open;
+import Anoma.Identity.Internal open;
+
+--- Module for the Secp256k1 elliptic curve.
+---
+--- 1. To obtain a private key:
+--- priv := ;Secp256k1.PrivateKey.fromInternalIdentity; someIdentity
+--- 2. To obtain a public key:
+--- pub := ;Secp256k1.PublicKey.mk; priv
+--- 3. To sign a message:
+--- signature := ;sign; myMessage priv
+--- 4. To verify a message
+--- ;verify; myMessage signature pub
+module Secp256k1;
+  type PrivateKey := privateMk ByteArray
+  with
+    --- Create a ;PrivateKey; from an ;InternalIdentity;
+    mk : InternalIdentity -> PrivateKey := fromInternalIdentity;
+
+    fromInternalIdentity : InternalIdentity -> PrivateKey :=
+      InternalIdentity.toByteArray >> fromByteArray;
+
+    toNat : PrivateKey -> Nat :=
+      toByteArray >> ByteArray.toAnomaContents >> AnomaAtom.toNat;
+
+    fromByteArray : ByteArray -> PrivateKey := privateMk;
+
+    toByteArray : PrivateKey -> ByteArray
+      | (privateMk b) := b;
+
+    size : Nat := 32;
+
+    instance
+    PrivateKey-FixedSize : FixedSize PrivateKey := FixedSize.mk size;
+  end;
+
+  type PublicKey := privateMk ByteArray
+  with
+    --- This is the main way to generate public keys.
+    mk : PrivateKey -> PublicKey := fromPrivateKey;
+
+    --- Generate a ;PublicKey; from a ;PrivateKey;
+    fromPrivateKey : PrivateKey -> PublicKey :=
+      PrivateKey.toNat >> Private.pubKey >> fromNat;
+
+    toByteArray : PublicKey -> ByteArray
+      | (privateMk b) := b;
+
+    fromNat : Nat -> PublicKey := AnomaAtom.fromNat >> fromAnomaAtom;
+
+    toNat : PublicKey -> Nat := toByteArray >> ByteArray.toNat;
+
+    instance
+    PublicteKey-FixedSize : FixedSize PublicKey := FixedSize.mk size;
+
+    fromAnomaAtom : AnomaAtom -> PublicKey :=
+      ByteArray.fromAnomaContents size >> privateMk;
+
+    --- The size of the produced public keys is always sixty-five bytes
+    size : Nat := 65;
+  end;
+
+  --- See ;sign; and ;verify;
+  type Signature := privateMk ByteArray
+  with
+    instance
+    PublicteKey-FixedSize : FixedSize Signature := FixedSize.mk size;
+
+    fromAnomaAtom : AnomaAtom -> Signature :=
+      ByteArray.fromAnomaContents size >> privateMk;
+
+    fromNat : Nat -> Signature := AnomaAtom.fromNat >> fromAnomaAtom;
+
+    toByeArray : Signature -> ByteArray
+      | (privateMk b) := b;
+
+    toNat : Signature -> Nat := toByeArray >> ByteArray.toNat;
+
+    size : Nat := 64;
+  end;
+
+  sign (msg : AnomaAtom) (priv : PrivateKey) : Signature :=
+    Private.sign (AnomaAtom.toNat msg) (PrivateKey.toNat priv)
+      |> Private.PrimitiveSignature.bin
+      |> Signature.fromNat;
+
+  verify (msg : AnomaAtom) (sig : Signature) (pub : PublicKey) : Bool :=
+    Private.verify
+      (AnomaAtom.toNat msg)
+      (Signature.toNat sig)
+      (PublicKey.toNat pub);
+
+  module Private;
+    builtin secp256k1-public-key
+    axiom pubKey (privKey : Nat) : Nat;
+
+    type PrimitiveSignature :=
+      mk@{
+        bin : Nat;
+        --- currently never used
+        recoveryId : Nat;
+      };
+
+    builtin secp256k1-sign-compact
+    axiom sign (msg privKey : Nat) : PrimitiveSignature;
+
+    builtin secp256k1-verify
+    axiom verify (msg signature pubKey : Nat) : Bool;
+  end;
+end;

Package.juvix

@@ -9,7 +9,7 @@ package : Package :=
       mkVersion@{
         major := 0;
         minor := 13;
-        patch := 0;
+        patch := 1;
       };
     dependencies :=
       [

juvix.lock.yaml

@@ -2,7 +2,7 @@
 # Do not edit this file manually.
 
 version: 2
-checksum: 7a1c0a81eaeccccd15bd8132ec0eb5238f610b3aec8ac13993ab49331c8d3d0e
+checksum: f2d0e43e920616ddf14f28e97493c325e76af638d0cc02f812494349edde3917
 dependencies:
 - git:
     name: anoma_juvix-stdlib