Acceptance test: override immutable bit with edit_template (mustache)

Added acceptance test to test that the edit_template attribute (with
mustache) of the files promise can override the immutable bit of the
destination file.

It just works. No need to edit the code further.

Ticket: ENT-10961, CFE-1840
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_09.cf

@@ -0,0 +1,88 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using edit_template
+# attribute with mustache
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_09.txt"
+      create => "true",
+      content => "Hello olehermanse!";
+
+  commands:
+    "chattr +i /tmp/immutable_09.txt"
+      contain => in_shell;
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the edit_template attribute with mustache";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  vars:
+    "object"
+      data => '{ "user": "larsewi" }';
+
+  files:
+    "/tmp/immutable_09.txt"
+      fsattrs => set_immutable,
+      template_method => "inline_mustache",
+      edit_template_string => "Hello {{{user}}}!",
+      template_data => @(object);
+}
+
+bundle agent check
+{
+  vars:
+    "expected"
+      string => "Hello larsewi!";
+    "actual"
+      string => readfile("/tmp/immutable_09.txt");
+
+  classes:
+    "ok"
+      expression => strcmp("$(actual)", "$(expected)");
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "Expecting '$(expected)', got '$(actual)'";
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_09.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_09.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+    "/tmp/immutable_09.txt.cf-before-edit"
+      delete => tidy;
+}