Add a convention plugin

Author: durimkryeziu

buildSrc/build.gradle

@@ -0,0 +1,7 @@
+plugins {
+    id 'groovy-gradle-plugin'
+}
+
+repositories {
+    gradlePluginPortal()
+}

buildSrc/settings.gradle

@@ -0,0 +1 @@
+rootProject.name = 'common-conventions'

buildSrc/src/main/groovy/com.craftsmanshipinsoftware.common-conventions.gradle

@@ -0,0 +1,21 @@
+plugins {
+    id 'java'
+}
+
+repositories {
+    mavenCentral()
+}
+
+java {
+    toolchain {
+        languageVersion = JavaLanguageVersion.of(21)
+    }
+}
+
+testing {
+    suites {
+        test {
+            useJUnitJupiter()
+        }
+    }
+}

characters-count/build.gradle

@@ -1,10 +1,7 @@
 plugins {
     id 'application'
-    id 'org.openjfx.javafxplugin' version '0.1.0'
-}
-
-repositories {
-    mavenCentral()
+    alias(libs.plugins.javafxplugin)
+    id 'com.craftsmanshipinsoftware.common-conventions'
 }
 
 javafx {
@@ -19,9 +16,4 @@ application {
 dependencies {
     testImplementation(libs.assertj.core)
     testImplementation(libs.junit.jupiter)
-    testRuntimeOnly(libs.junit.platform.launcher)
-}
-
-tasks.named('test') {
-    useJUnitPlatform()
 }

gradle/libs.versions.toml

@@ -2,9 +2,11 @@
 [versions]
 assertj-core = "3.26.3"
 junit-jupiter = "5.11.0"
-junit-platform-launcher = "1.11.0"
+javafxplugin = "0.1.0"
 
 [libraries]
 assertj-core = { module = "org.assertj:assertj-core", version.ref = "assertj-core" }
 junit-jupiter = { module = "org.junit.jupiter:junit-jupiter", version.ref = "junit-jupiter" }
-junit-platform-launcher = { module = "org.junit.platform:junit-platform-launcher", version.ref = "junit-platform-launcher" }
+
+[plugins]
+javafxplugin = { id = "org.openjfx.javafxplugin", version.ref = "javafxplugin" }

printing-quotes/build.gradle

@@ -1,16 +1,8 @@
 plugins {
-    id 'java'
-}
-
-repositories {
-    mavenCentral()
+    id 'com.craftsmanshipinsoftware.common-conventions'
 }
 
 dependencies {
     testImplementation(libs.assertj.core)
     testImplementation(libs.junit.jupiter)
 }
-
-tasks.named('test') {
-    useJUnitPlatform()
-}

saying-hello/build.gradle

@@ -1,17 +1,8 @@
 plugins {
-    id 'java'
-}
-
-repositories {
-    mavenCentral()
+    id 'com.craftsmanshipinsoftware.common-conventions'
 }
 
 dependencies {
     testImplementation(libs.assertj.core)
     testImplementation(libs.junit.jupiter)
-    testRuntimeOnly(libs.junit.platform.launcher)
-}
-
-tasks.named('test') {
-    useJUnitPlatform()
 }