Compilation error: 'bus_parallel16' in namespace 'lgfx' does not name a type

[mdbiggio]

I am having an issue after updating to the latest version of this library where in the LGFX class below I have : " lgfx::bus_parallel16 _bus_instance; " my arduino compiler is saying that "bus_parallel16" in namespace 'lgfx' does not name a type, where in the previous version it was compiling correctly. Am I missing something here? maybe a change in how this is declared with the new version?

Thanks for your help in advance... My code is below

#include <FT6236.h>

FT6236 ts = FT6236();

#define LGFX_USE_V1

#include <LovyanGFX.hpp>

#define LCD_BLK 46

#include <Arduino.h>

//#define uint16_t green = 0x07E0;
//#define uint16_t cyan = 0x07FF;
//#define uint16_t blue = 0x001F;



class LGFX : public lgfx::LGFX_Device
{
    lgfx::Panel_ILI9488 _panel_instance;
    lgfx::bus_parallel16 _bus_instance;

  public:
    LGFX(void)
    {
      {
        auto cfg = _bus_instance.config();

        cfg.port = 0;
        cfg.freq_write = 20000000;
        cfg.pin_wr = 18;
        cfg.pin_rd = 48;
        cfg.pin_rs = 45;

        cfg.pin_d0 = 47;
        cfg.pin_d1 = 21;
        cfg.pin_d2 = 14;
        cfg.pin_d3 = 13;
        cfg.pin_d4 = 12;
        cfg.pin_d5 = 11;
        cfg.pin_d6 = 10;
        cfg.pin_d7 = 9;
        cfg.pin_d8 = 3;
        cfg.pin_d9 = 8;
        cfg.pin_d10 = 16;
        cfg.pin_d11 = 15;
        cfg.pin_d12 = 7;
        cfg.pin_d13 = 6;
        cfg.pin_d14 = 5;
        cfg.pin_d15 = 4;

        _bus_instance.config(cfg);
        _panel_instance.setBus(&_bus_instance);
      }

      {
        auto cfg = _panel_instance.config();

        cfg.pin_cs = -1; 
        cfg.pin_rst = -1; 
        cfg.pin_busy = -1; 
       

        cfg.memory_width = 320; 
        cfg.memory_height = 480; 
        cfg.panel_width = 320; 
        cfg.panel_height = 480; 
        cfg.offset_x = 0; 
        cfg.offset_y = 0; 
        cfg.offset_rotation = 1; 
        cfg.dummy_read_pixel = 8; 
        cfg.dummy_read_bits = 1; 
        cfg.readable = true; 
        cfg.invert = false; 
        cfg.rgb_order = false; 
        cfg.dlen_16bit = true; 
        cfg.bus_shared = true; 
        _panel_instance.config(cfg);
      }

      setPanel(&_panel_instance);
    }
};

LGFX lcd;


/*************************************************************
  Blynk Setup
 *************************************************************/

/* Fill-in information from Blynk Device Info here */
#define BLYNK_TEMPLATE_ID ""
#define BLYNK_TEMPLATE_NAME "Quickstart Template"
#define BLYNK_AUTH_TOKEN ""

/* Comment this out to disable prints and save space */
#define BLYNK_PRINT Serial


#include <WiFi.h>
#include <WiFiClient.h>
#include <BlynkSimpleEsp32.h>

// Your WiFi credentials.
// Set password to "" for open networks.
char ssid[] = "*****";
char pass[] = "*****";

BlynkTimer timer;

// This function is called every time the Virtual Pin 0 state changes
BLYNK_WRITE(V0)
{
  // Set incoming value from pin V0 to a variable
  int enable = param.asInt();
  Serial.println("Enable has changed to: " + String(enable) + " !");

  // Update state
  Blynk.virtualWrite(V1, enable);
}
BLYNK_WRITE(V3)
{
  int Cool_Heat = param.asInt();
  Serial.println("Cool_Heat has changed to: " + String(Cool_Heat));
}

// This function is called every time the device is connected to the Blynk.Cloud
BLYNK_CONNECTED()
{
  // Change Web Link Button message to "Congratulations!"
  Blynk.setProperty(V3, "offImageUrl", "https://static-image.nyc3.cdn.digitaloceanspaces.com/general/fte/congratulations.png");
  Blynk.setProperty(V3, "onImageUrl",  "https://static-image.nyc3.cdn.digitaloceanspaces.com/general/fte/congratulations_pressed.png");
  Blynk.setProperty(V3, "url", "https://docs.blynk.io/en/getting-started/what-do-i-need-to-blynk/how-quickstart-device-was-made");
}

// This function sends Arduino's uptime every second to Virtual Pin 2.
void myTimerEvent()
{
  // You can send any value at any time.
  // Please don't send more that 10 values per second.
  Blynk.virtualWrite(V2, millis() / 1000);
  Blynk.virtualWrite(V4, int(random(1,100)));
}

void setup()
{
  
  // Debug console
  Serial.begin(115200);


  // Blynk ****************************
  Blynk.begin(BLYNK_AUTH_TOKEN, ssid, pass);
  // You can also specify server:
  //Blynk.begin(BLYNK_AUTH_TOKEN, ssid, pass, "blynk.cloud", 80);
  //Blynk.begin(BLYNK_AUTH_TOKEN, ssid, pass, IPAddress(192,168,1,100), 8080);

  // Setup a function to be called every second
  timer.setInterval(1000L, myTimerEvent);

  // LGFX *****************************
  ts.begin(40, 38, 39);

  lcd.init();

  lcd.fillScreen(TFT_BLACK);

  pinMode(LCD_BLK, OUTPUT);
  digitalWrite(LCD_BLK, HIGH);
  lcd.setTextColor(TFT_RED);
  lcd.setTextSize(2);
  lcd.setTextFont(2);

}

void loop()
{
  // Blynk ****************************
  Blynk.run();
  timer.run();
  // You can inject your own code or combine it with other sketches.
  // Check other examples on how to communicate with Blynk. Remember
  // to avoid delay() function!

  // LGFX *****************************

  lcd.fillScreen(TFT_BLACK);
  lcd.setCursor(50, 200);
  lcd.printf("                  ");
  lcd.setCursor(50, 200);
  lcd.printf("Touch Coordinates:");

  if (ts.touched())
  {
      // Retrieve a point
      TS_Point p = ts.getPoint();

      String xCoord = String(p.y);
      String yCoord = String(abs(p.x-320));

      // Print coordinates to the serial output
      Serial.print("X: ");
      Serial.print(p.x);
      Serial.print(" Y : ");
      Serial.println(p.y);

      lcd.setCursor(50, 200);
      lcd.printf("                  ");
      lcd.setCursor(50, 250);
      lcd.printf("X: ");
      lcd.setCursor(80, 250);
      lcd.print(xCoord);
      lcd.setCursor(180, 250);
      lcd.printf("Y: ");
      lcd.setCursor(210, 250);
      lcd.print(yCoord);
            

  }
  
}

[tobozo]

the type is lgfx::Bus_Parallel16 (with capital B and capital P) not lgfx::bus_parallel16

[mdbiggio]

thanks for your reply!
Unfortunately, I have tried that as well with the same result. Any more ideas?

"Compilation error: 'Bus_Parallel16' in namespace 'lgfx' does not name a type"

[mdbiggio]

@tobozo If you have the time, would you be able to DM somewhere to help me on this issue?

[tobozo]

maybe add this before the class declaration?

#include <lgfx/v1/platforms/esp32s3/Bus_Parallel16.hpp>

[mdbiggio]

I appreciate the help but I figured out my problem. I had selected the wrong board in the IDE. I had the "esp32 dev module" selected where I needed the "esp32s3 dev module selected.

[TorridestEye]

im having issues with the S3 dev board

[TorridestEye]

#include <Arduino.h>
#include <LovyanGFX.hpp>

// ─── LGFX Device for CYD ESP32-4827S043 ───────────────────────────────────────
class LGFX_CYD_4827S043 : public lgfx::LGFX_Device {
lgfx::Bus_Parallel16 _bus; // 16-bit parallel RGB bus
lgfx::Panel_RGB _panel; // RGB666 panel driver
public:
LGFX_CYD_4827S043() {
// 1) Configure the 16-bit parallel bus
auto bus_cfg = _bus.config();
bus_cfg.pin_pclk = 42; // PCLK
bus_cfg.pin_de = 40; // Data Enable
bus_cfg.pin_hsync = 39; // HSYNC
bus_cfg.pin_vsync = 41; // VSYNC
// 16 data pins: R0–R4, G0–G5, B0–B4
constexpr int8_t data_pins[16] = {
45, 48, 47, 21, 14, // R0–R4
5, 6, 7, 15, 16, // G0–G5
4, 8, 3, 46, 9, // B0–B4
-1 // unused (pad to 16)
};
for (int i = 0; i < 16; ++i) bus_cfg.pin_data[i] = data_pins[i];
_bus.config(bus_cfg);

// 2) Configure the panel itself
auto p_cfg = _panel.config();
p_cfg.pin_rst          = -1;    // no dedicated reset pin
p_cfg.memory_width     = 480;
p_cfg.memory_height    = 272;
p_cfg.panel_width      = 480;
p_cfg.panel_height     = 272;
p_cfg.offset_x         = 0;
p_cfg.offset_y         = 0;
p_cfg.offset_rotation  = 0;
p_cfg.dummy_read_pixel = 0;
p_cfg.dummy_read_bits  = 1;
p_cfg.readable         = false;
p_cfg.invert           = false;
p_cfg.rgb_order        = false;
p_cfg.bus_shared       = true;
_panel.config(p_cfg);

// 3) Link bus→panel→LGFX_Device
_panel.setBus(&_bus);
setPanel(&_panel);

}
};
// instantiate a single display object
static LGFX_CYD_4827S043 display;

// ─── Sketch Entry ─────────────────────────────────────────────────────────────
void setup() {
// backlight on GPIO 2
pinMode(2, OUTPUT);
digitalWrite(2, HIGH);

// init display
display.init();

// fill screen red
display.fillScreen(TFT_RED);
}

void loop() {
// nothing else to do
}

[TorridestEye]

Compilation error: 'Panel_RGB' in namespace 'lgfx' does not name a type