Switching between A2DP, URL and i2s sources

[HostXnine]

Hello. First of all thank you for your amazing work I really appreciate what you do to make us stuff easier to work with audio.

I'm really struggling with this one, I have red a lot in your wiki, documentation and here in discussions but I simply can't figure it out.

I'm tying to make a stereo system where I can witch between different sources, I would like to switch between A2DP source, URL source and an external i2s source. The output is the same for both sources an external DAC (PCM5201a). I'm still waiting to get the component for the external i2s source thus this is yet not in the code.

Is it possible to do what I'm trying to do? I've red that you can't use WIFI and Bluetooth at the same time but my intention is not to run them simultaneous. I would switch between them.

Here is my amateur code which results in a reboot of the esp32, I've tried a few different things but this is basically the best I've come up with... I would just like to switch between sources:

To switch between menu items send "5" in the serial.

#include <Arduino.h>
#include "AudioTools.h"
#include "BluetoothA2DPSink.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"

int irReceivedData;
int menu = 1;
int flag = 1;
//Audio
#define I2S_WS_PIN 15 //aka LRCLK
#define I2S_BCK_PIN 14 //aka SCK
#define I2S_DATA_PIN 18
#define I2S_MCK_PIN 3  // must be 0,1 or 3 - only for ESP_IDF_VERSION_MAJOR >= 4
#define I2S_DATA_RX_PIN 19

  //Bluetooth
I2SStream i2s;
BluetoothA2DPSink a2dp_sink(i2s);

  //i2s stream for internet radio and external i2s input
AudioInfo info(48000, 2, 24);

  //URL Source
const char *urls[] = {
  "http://stream.srg-ssr.ch/m/rsj/mp3_128"
};
const char *wifi = "****";
const char *password = "****;

URLStream urlStream(wifi, password);
AudioSourceURL source(urlStream, urls, "audio/mp3");
MP3DecoderHelix decoder;
AudioPlayer player(source, i2s, decoder);

void servoControl() {
  switch(irReceivedData) {   
    case 53: //menu button wokwi simulator 226, real remote 114, key stroke 5 code 53
      if (menu < 3) {
        menu++;
      } else {
        menu = 1;
      }
      break;
  }
}

void menuControl() {
  switch (menu) {
    case 1:
      if (flag == 1) {
      flag = 2;
      Serial.println("TV");
      a2dp_sink.stop();
      }
      break;
    case 2:
      if (flag == 2) {
      flag = 3;
      Serial.println("FM");
      player.begin();
      }
      player.copy();
      break;
    case 3:
      if (flag == 3) {
      flag = 1;
      Serial.println("Bluetooth");
      player.end();
      player.stop();
      a2dp_sink.start("MyEsp");
      }
      break;
  }
}

void setup() {
  //Debugging
  Serial.begin(115200);
  
  // Audio
  auto cfg = i2s.defaultConfig(TX_MODE);
  cfg.copyFrom(info); 
  cfg.i2s_format = I2S_STD_FORMAT;
  cfg.pin_ws = I2S_WS_PIN;
  cfg.pin_bck = I2S_BCK_PIN;
  cfg.pin_data = I2S_DATA_PIN;
  i2s.begin(cfg);

}

void debug() {
  irReceivedData = Serial.read();
  delay(500);
}

void loop() {
  debug();
  servoControl();
  menuControl();
}

I'm really grateful for any help.

[pschatzmann]

Microcontroller have only limited resources and you need to first investigate the RAM requirements of each of your scenario. Measure, calculate and design it properly (e.g. by using PSRAM) or by rebooting into your specific scenario.

When you change the scenario, don't forget to close all resources to release the memory and keep in mind that for A2DP only a limited amount of RAM is released, so that it can be restarted again.

Learn how to analyze the back trace to find out where it is currently failing. You can also set the log level to Debug and add Serial.println() to figure out where it is failing....

[pschatzmann]

Sure, just make sure that at any point of time you only write to the Audio Sink from one Audio Source only.
I confirm that calling close releases the resources.

In regard of PSRAM maybe this helps

[HostXnine]

Thank you for the link it really helped me out to get the right info on how to debug with tracing HEAP usage. Unfortunately I can't use PSRAM because I have an ESP32-Wroom-32D which doesn't have that. But you gave me a great idea of rebooting into different instances, which I'll most probably implement since managing HEAP storage with pointers to object was working until I was trying to connect to Bluetooth with a device.

[munkerench]

Thinking about this exact subject and how to get it working. I will give your code a go on an ESP32-S3 and see what I can figure out. This is my first try in the audio code area so it may be a minute. Will post back here.

[pschatzmann]

Please read the documentation: the S3 does not support A2DP!

[munkerench]

Just getting started and will read the docs. I have the AIThinker A1A board. It is very large but I guess I will have to make it work. The spec shows it has 4 mg PSRAM and supports A2DP. Thanks for the heads up, I assumed the S3 would have A2DP.

[HostXnine]

I did managed it to switch between sources by rebooting into different instances. It was a fun learning experience. I really have to give you credit for pointing me to this idea since I would come with it up easily because I'm not experienced in this kind of work. After all I'm just doing it for hobby :).

To give something back to the community here is the part I've changed from the above code:

added variables to RTC slow memory:

RTC_NOINIT_ATTR int menu; // for identifying menu selection saved in slow memory so it is not initialized during reboot
RTC_NOINIT_ATTR int flag; // for the menu so that the code in the switch clause executes only once
esp_reset_reason_t resetReason = esp_reset_reason(); // reset reason for when to initialize variables to 1

void initRtcVariable() { // this function goes into setup()
  if (resetReason != ESP_RST_SW) {
    menu = 1;
    flag = 1;
  }
}

Added restarts between menu choices. Well, it's not a good code but it works ;).

void restart() {
  if (flag == menu) {
    flag++;
    menu++;
    esp_restart();
  }
}

void menuControl() {
  switch (menu) {
    case 1:
      if (flag == menu) {
        flag++;
        display.clearDisplay();
        display.setCursor(12, 0);
        display.println("TV");
        display.display();
        a2dp_sink.stop();
        Serial.println("TV");
      }
      break;
    case 2:
      restart();
      break;
    case 3:
      if (flag == menu) {
        flag++;
        display.clearDisplay();
        display.setCursor(12, 0);
        display.println("FM");
        display.display();
        player.begin();
        Serial.println("FM");
      }
      player.copy();
      break;
    case 4:
      restart();
      break;
    case 5:
      if (flag == menu) {
        flag++;
        display.clearDisplay();
        display.drawBitmap(30, 0, bluetooth_icon_64x64_bmp, 64 ,64, 1);
        display.display();
        Serial.println("Bluetooth");
        a2dp_sink.start("MojESP");
      }
      break;
    case 6:
      if (flag == menu) {
        flag = 1;
        menu = 1;
        esp_restart();
      }
      break;
  }
}

[pschatzmann]

Interesting approach: you could also use the The ESP32 NVS (Non-Volatile Storage) API.

[HostXnine]

Thanks for the suggestion I didn't knew about the NVS storage that's why I've used RTC slow memory. My next thing to do now is to power up and down (or at least to make it consume less power) the board using the ULP and RTC memory. I'm using IR remote for controlling the ESP that why I need a CPU to decode the IR signal but this is a totally different topic unrelated to this library.