Added get and set detection threshold functionality.

Author: PPVJM

examples/Example8_SetGetDetectionThresholds/Example8_SetGetDetectionThresholds.ino

@@ -0,0 +1,126 @@
+/*
+  Reading distance from the laser based VL53L1X
+  By: Nathan Seidle
+  Revised by: Andy England and Ricardo Ramos
+  SparkFun Electronics
+  Date: January 21st, 2022
+  License: This code is public domain but you buy me a beer if you use this and we meet someday (Beerware license).
+
+  SparkFun labored with love to create this code. Feel like supporting open source hardware? 
+  Buy a board from SparkFun! https://www.sparkfun.com/products/14667
+
+  This example sets high and low thresholds for detection.
+
+  Are you getting weird readings? Be sure the vacuum tape has been removed from the sensor.
+*/
+
+#include <Wire.h>
+#include "SparkFun_VL53L1X.h" //Click here to get the library: http://librarymanager/All#SparkFun_VL53L1X
+
+//Optional interrupt and shutdown pins.
+#define SHUTDOWN_PIN 2
+#define INTERRUPT_PIN 3
+
+SFEVL53L1X distanceSensor;
+//Uncomment the following line to use the optional shutdown and interrupt pins.
+//SFEVL53L1X distanceSensor(Wire, SHUTDOWN_PIN, INTERRUPT_PIN);
+
+void setup(void)
+{
+  Wire.begin();
+
+  Serial.begin(115200);
+  Serial.println("VL53L1X Qwiic Test");
+
+  if (distanceSensor.begin() != 0) //Begin returns 0 on a good init
+  {
+    Serial.println("Sensor failed to begin. Please check wiring. Freezing...");
+    while (1)
+      ;
+  }
+  Serial.println("Sensor online!");
+
+  DetectionConfig dc;               // struct instance which holds the detection configuration
+  dc.IntOnNoTarget = 1;              // No longer used - just use 1 per ST
+  dc.distanceMode = DISTANCE_SHORT; // short distance mode
+  dc.thresholdHigh = 300;           // high threshold of 300 mm
+  dc.thresholdLow = 70;             // low threshold of 70 mm
+  dc.windowMode = WINDOW_IN;        // will measure and trigger interrrupt when measurement fall between 70 and 300 mm
+
+  if(distanceSensor.setThresholdConfig(&dc) == true)
+  {
+    Serial.println("Thresholds programmed. Reading configuration back...");
+    dc = {};
+    if(distanceSensor.getThresholdConfig(&dc) == true)
+    {
+      Serial.print("IntOnNoTarget: ");
+      Serial.println(dc.IntOnNoTarget);
+      Serial.print("Distance Mode: ");
+
+      if(dc.distanceMode == DISTANCE_SHORT)
+        Serial.println("DISTANCE_SHORT (0)");
+      else
+        Serial.println("DISTANCE_LONG (1)");
+      
+      Serial.print("Threshold High: ");
+      Serial.println(dc.thresholdHigh);
+      Serial.print("Threshold Low: ");
+      Serial.println(dc.thresholdLow);
+      Serial.print("Window mode: ");
+      switch (dc.windowMode)
+      {
+      case WINDOW_BELOW:
+        Serial.println("WINDOW_BELOW (0)");
+        break;
+      
+      case WINDOW_ABOVE:
+        Serial.println("WINDOW_ABOVE (1)");
+        break;
+
+      case WINDOW_OUT:
+        Serial.println("WINDOW_OUT (2)");
+        break;
+
+      case WINDOW_IN:
+        Serial.println("WINDOW_IN (3)");
+        break;
+
+      default:
+        break;
+      }
+    }
+  }
+  else
+  {
+    Serial.println("Could not set threshold configuration.");
+  }
+  Serial.println("Starting measurements in 2 seconds.");
+  delay(2000);
+  Serial.println("Measurements started!");
+
+}
+
+void loop(void)
+{
+  distanceSensor.startRanging(); //Write configuration bytes to initiate measurement
+
+  while (!distanceSensor.checkForDataReady())
+  {
+    delay(1);
+  }
+  int distance = distanceSensor.getDistance(); //Get the result of the measurement from the sensor
+  distanceSensor.clearInterrupt();
+
+  distanceSensor.stopRanging();
+
+  Serial.print("Distance(mm): ");
+  Serial.print(distance);
+
+  float distanceInches = distance * 0.0393701;
+  float distanceFeet = distanceInches / 12.0;
+
+  Serial.print("\tDistance(ft): ");
+  Serial.print(distanceFeet, 2);
+
+  Serial.println();
+}

src/SparkFun_VL53L1X.cpp

@@ -54,7 +54,7 @@ bool SFEVL53L1X::checkID()
 {
 	uint16_t sensorId;
 	_device->VL53L1X_GetSensorId(&sensorId);
-	if ( (sensorId == 0xEACC) || (sensorId == 0xEBAA) )
+	if ((sensorId == 0xEACC) || (sensorId == 0xEBAA))
 		return true;
 	return false;
 }
@@ -360,3 +360,43 @@ void SFEVL53L1X::calibrateXTalk(uint16_t targetDistanceInMm)
 	uint16_t xTalk = getXTalk();
 	_device->VL53L1X_CalibrateXtalk(targetDistanceInMm, &xTalk);
 };
+
+bool SFEVL53L1X::setThresholdConfig(DetectionConfig *config)
+{
+	VL53L1X_ERROR error = _device->VL53L1X_SetDistanceThreshold(config->thresholdLow, config->thresholdHigh,
+																(uint8_t)config->windowMode, (uint8_t)config->IntOnNoTarget);
+	return (error == VL53L1_ERROR_NONE);
+}
+
+bool SFEVL53L1X::getThresholdConfig(DetectionConfig *config)
+{
+	uint16_t temp16 = 0;
+
+	VL53L1X_ERROR error = _device->VL53L1X_GetDistanceMode(&temp16);
+	if (error != 0)
+		return false;
+	else
+		config->distanceMode = temp16;
+
+	error = _device->VL53L1X_GetDistanceThresholdWindow(&temp16);
+	if (error != 0)
+		return false;
+	else
+		config->windowMode = temp16;
+
+	config->IntOnNoTarget = 1;
+
+	error = _device->VL53L1X_GetDistanceThresholdLow(&temp16);
+	if (error != 0)
+		return false;
+	else
+		config->thresholdLow = temp16;
+
+	error = _device->VL53L1X_GetDistanceThresholdHigh(&temp16);
+	if (error != 0)
+		return false;
+	else
+		config->thresholdHigh = temp16;
+
+	return true;
+}

src/SparkFun_VL53L1X.h

@@ -30,6 +30,22 @@
 #include "vl53l1_error_codes.h"
 #include "vl53l1x_class.h"
 
+#define DISTANCE_SHORT 	0
+#define DISTANCE_LONG 	1
+#define WINDOW_BELOW	0
+#define WINDOW_ABOVE	1
+#define WINDOW_OUT		2
+#define WINDOW_IN		3
+
+struct DetectionConfig
+{
+	uint16_t distanceMode = DISTANCE_SHORT;	// distance mode : DISTANCE_SHORT (0) or DISTANCE_LONG (1)
+	uint16_t windowMode = WINDOW_IN;		// window mode : WINDOW_BELOW (0), WINDOW_ABOVE (1), WINDOW_OUT (2), WINDOW_IN (3)
+	uint8_t IntOnNoTarget = 1;				// = 1 (No longer used - just use 1)
+	uint16_t thresholdHigh = 0;				// (in mm) :  the threshold above which one the device raises an interrupt if Window = 1
+	uint16_t thresholdLow = 0;				// (in mm) : the threshold under which one the device raises an interrupt if Window = 0
+};
+
 class SFEVL53L1X
 {
 	public:
@@ -108,6 +124,9 @@ class SFEVL53L1X
 	void startTemperatureUpdate(); //Recalibrates the sensor for temperature changes. Run this any time the temperature has changed by more than 8°C
 	void calibrateOffset(uint16_t targetDistanceInMm); //Autocalibrate the offset by placing a target a known distance away from the sensor and passing this known distance into the function.
 	void calibrateXTalk(uint16_t targetDistanceInMm); //Autocalibrate the crosstalk by placing a target a known distance away from the sensor and passing this known distance into the function.
+	bool setThresholdConfig(DetectionConfig* config); //Sets threshold configuration struct
+	bool getThresholdConfig(DetectionConfig* config); //Gets current threshold settings. Returns false on error, true otherwise. Stores results in pointer to struct argument.
+
 	private:
 	TwoWire *_i2cPort;
 	int _shutdownPin;