nix: Add Nix Flake support

This commit consists of the following changes:

- `default.nix`/`shell.nix`
  This allows for legacy Nix tooling like `nix-build`/`nix-shell` to work.
- `flake.nix`
  This is for the (new) Nix Flake support.
- `flake.lock`
  As above, but for tracking Flake inputs.
- `.envrc`
  This allows for a fully self-contained developer environment to be
  setup with Nix.
- `nix/default.nix`
  This is the main package derivation. Both this repo & Nixpkgs are
  derived from the same codebase.

Closes: #38

Author: shymega

.envrc

@@ -0,0 +1 @@
+use flake

CMakeLists.txt

@@ -42,6 +42,7 @@ pkg_check_modules(LIBWAYLAND_CLIENT REQUIRED wayland-client)
 
 execute_process(COMMAND git submodule update --init --recursive
                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
+
 add_subdirectory(modules/xrealInterfaceLibrary/interface_lib)
 
 # Set the library directory based on architecture

default.nix

@@ -0,0 +1,9 @@
+(import (
+  let
+    lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+  in
+  fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+    sha256 = lock.nodes.flake-compat.locked.narHash;
+  }
+) { src = ./.; }).defaultNix

flake.lock

@@ -0,0 +1,41 @@
+{
+  description = "Nix Flake for XRLinuxDriver";
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs?ref=nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+  };
+  outputs = {
+    self,
+    nixpkgs,
+    flake-utils,
+    ...
+  }: let
+    systems = [
+      "x86_64-linux"
+      "aarch64-linux"
+    ];
+  in
+    flake-utils.lib.eachSystem systems
+    (
+      system: let
+        pkgs = import nixpkgs {
+          inherit system;
+        };
+      in
+        with pkgs; {
+          packages = {
+            xrlinuxdriver = callPackage ./nix {inherit self;};
+            default = self.packages.${system}.xrlinuxdriver;
+          };
+
+          devShells.default = mkShell {inputsFrom = lib.singleton self.packages.${system}.default;};
+        }
+    )
+    // {
+      overlays.default = final: prev: {inherit (self.packages.${final.system}) xrlinuxdriver;};
+    };
+}

flake.nix

@@ -0,0 +1,114 @@
+{
+  self,
+  lib,
+  pkgs,
+  stdenv,
+  fetchFromGitLab,
+  libusb1,
+  curl,
+  openssl,
+  libevdev,
+  json_c,
+  hidapi,
+  wayland,
+  cmake,
+  pkg-config,
+  python3,
+  libffi,
+  autoPatchelfHook,
+  ...
+}: let
+  pythonEnv = python3.withPackages (ps: [ps.pyyaml]);
+  buildInputs = [
+    curl
+    hidapi
+    json_c
+    libevdev
+    libffi
+    libusb1
+    openssl
+    stdenv.cc.cc.lib
+    wayland
+  ];
+  arch =
+    if pkgs.system == "aarch64-linux"
+    then "aarch64"
+    else if pkgs.system == "x86_64-linux"
+    then "x86_64"
+    else throw "Unsupported system ${pkgs.system}";
+in
+  stdenv.mkDerivation rec {
+    pname = "xrlinuxdriver";
+    version = "0.12.0.1";
+
+    srcs = [
+      (fetchFromGitLab rec {
+        domain = "gitlab.com";
+        owner = "TheJackiMonster";
+        repo = "nrealAirLinuxDriver";
+        rev = "d101fae45797e1bc6bfa3716cacb8a1002cb6252";
+        hash = "sha256-cohOFhdIIBfvO5gbF5fvPIXQFFsdWW2TTkdHzWNdUcc=";
+        fetchSubmodules = true;
+        name = "${repo}-src";
+      })
+      (lib.cleanSourceWith {
+        src = self;
+        name = "${pname}-src";
+      })
+    ];
+    sourceRoot = "${(builtins.elemAt srcs 1).name}";
+
+    postUnpack = let
+      nrealAirLinuxDriver = (builtins.elemAt srcs 0).name;
+    in ''
+      mkdir -p $sourceRoot/modules/xrealInterfaceLibrary
+      cp -R ${nrealAirLinuxDriver}/* $sourceRoot/modules/xrealInterfaceLibrary
+      chmod -R u+w $sourceRoot
+    '';
+
+    nativeBuildInputs = [
+      cmake
+      pkg-config
+      pythonEnv
+      autoPatchelfHook
+    ];
+    inherit buildInputs;
+
+    cmakeFlags = [
+      "-DCMAKE_SKIP_RPATH=ON"
+    ];
+    cmakeBuildDir = "build";
+    cmakeBuildType = "RelWithDebInfo";
+
+    installPhase = ''
+      mkdir -p $out/bin $out/usr/lib/systemd/user $out/usr/lib/udev/rules.d $out/usr/lib/${arch}
+      cp xrDriver ../bin/xr_driver_cli ../bin/xr_driver_verify $out/bin
+      cp ../udev/* $out/usr/lib/udev/rules.d/
+      cp ../lib/${arch}/* $out/usr/lib/${arch}/
+      cp ../systemd/xr-driver.service $out/usr/lib/systemd/user/
+      cp ${hidapi}/lib/libhidapi-hidraw.so.0 $out/usr/lib/
+    '';
+
+    preBuild = ''
+      addAutoPatchelfSearchPath $out/usr/lib/${arch}
+    '';
+
+    postInstall = ''
+      substituteInPlace $out/usr/lib/systemd/user/xr-driver.service \
+        --replace-fail "ExecStart={bin_dir}/xrDriver" "ExecStart=$out/bin/xrDriver" \
+        --replace-fail "{ld_library_path}" "$out/usr/lib/${arch}"
+    '';
+
+    doInstallCheck = false;
+    # The default release is a script which will do an impure download
+    # just ensure that the application can run without network
+
+    meta = with lib; {
+      homepage = "https://github.com/wheaney/XRLinuxDriver";
+      license = licenses.mit;
+      description = "Linux service for interacting with XR devices.";
+      mainProgram = "xrDriver";
+      maintainers = with maintainers; [shymega];
+      platforms = platforms.linux;
+    };
+  }

nix/default.nix

@@ -0,0 +1,12 @@
+# SPDX-FileCopyrightText: 2023 Dom Rodriguez <shymega@shymega.org.uk>
+#
+# SPDX-License-Identifier: GPL-3.0-only
+(import (
+  let
+    lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+  in
+  fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+    sha256 = lock.nodes.flake-compat.locked.narHash;
+  }
+) { src = ./.; }).shellNix