cmake: compiler: add support for Andes GCC and Clang

Add support for the Andes GCC/Clang (andes/andes-clang) compiler.
Both inherit the generic GCC/Clang flags with the following adjustments:

Andes GCC:
1. Set RISC-V -march with the Andes suffix (_xandes).
2. Enable Andes-specific machine options (e.g. -mexecit, -mext-dsp).

Andes Clang:
1. Apply the same -march suffix and machine options as Andes GCC.
2. Recognize the prefix 'riscv[32|64]-elf-clang' intead of 'clang'.
3. For Clang < 17, strip unsupported _zicsr/_zifencei from -march.

Signed-off-by: Jimmy Zheng <jimmyzhe@andestech.com>

Author: jimmyzhe

cmake/compiler/andes-clang/compiler_flags.cmake

@@ -0,0 +1,3 @@
+# SPDX-License-Identifier: Apache-2.0
+
+include(${ZEPHYR_BASE}/cmake/compiler/clang/compiler_flags.cmake)

cmake/compiler/andes-clang/generic.cmake

@@ -0,0 +1,3 @@
+# SPDX-License-Identifier: Apache-2.0
+
+find_program(CMAKE_C_COMPILER "${CROSS_COMPILE}clang" PATHS ${TOOLCHAIN_HOME} NO_DEFAULT_PATH REQUIRED)

cmake/compiler/andes-clang/target.cmake

@@ -0,0 +1,58 @@
+# SPDX-License-Identifier: Apache-2.0
+
+set(NOSTDINC "")
+
+# Note that NOSYSDEF_CFLAG may be an empty string, and
+# set_ifndef() does not work with empty string.
+if(NOT DEFINED NOSYSDEF_CFLAG)
+  set(NOSYSDEF_CFLAG -undef)
+endif()
+
+find_program(CMAKE_C_COMPILER "${CROSS_COMPILE}clang" PATHS ${TOOLCHAIN_HOME} NO_DEFAULT_PATH REQUIRED)
+find_program(CMAKE_CXX_COMPILER "${CROSS_COMPILE}clang++" PATHS ${TOOLCHAIN_HOME} NO_DEFAULT_PATH REQUIRED)
+
+if(SYSROOT_DIR)
+  # The toolchain has specified a sysroot dir, pass it to the compiler
+  list(APPEND TOOLCHAIN_C_FLAGS "--sysroot=${SYSROOT_DIR}")
+  list(APPEND TOOLCHAIN_LD_FLAGS "--sysroot=${SYSROOT_DIR}")
+endif()
+
+include(${ZEPHYR_BASE}/cmake/gcc-m-cpu.cmake)
+include(${ZEPHYR_BASE}/cmake/gcc-m-fpu.cmake)
+
+include(${ZEPHYR_BASE}/cmake/compiler/gcc/target_riscv.cmake)
+
+execute_process(
+  COMMAND ${CMAKE_C_COMPILER} --version
+  OUTPUT_VARIABLE full_version_output
+  )
+
+string(REGEX REPLACE ".*clang version ([0-9]+(\\.[0-9]+)*).*" "\\1" CLANG_COMPILER_VERSION "${full_version_output}")
+
+# Clang < 17 doesn't support zicsr, zifencei in -march, strip them.
+if(CLANG_COMPILER_VERSION VERSION_LESS "17.0.0")
+  foreach(var TOOLCHAIN_C_FLAGS TOOLCHAIN_LD_FLAGS LLEXT_APPEND_FLAGS)
+    list(TRANSFORM ${var} REPLACE "^-march=([^ ]*)_zicsr([^ ]*)$" "-march=\\1\\2")
+    list(TRANSFORM ${var} REPLACE "^-march=([^ ]*)_zifencei([^ ]*)$" "-march=\\1\\2")
+  endforeach()
+endif()
+
+foreach(file_name include/stddef.h)
+  execute_process(
+    COMMAND ${CMAKE_C_COMPILER} --print-file-name=${file_name}
+    OUTPUT_VARIABLE _OUTPUT
+    )
+  get_filename_component(_OUTPUT "${_OUTPUT}" DIRECTORY)
+  string(REGEX REPLACE "\n" "" _OUTPUT ${_OUTPUT})
+
+  list(APPEND NOSTDINC ${_OUTPUT})
+endforeach()
+
+foreach(isystem_include_dir ${NOSTDINC})
+  list(APPEND isystem_include_flags -isystem "\"${isystem_include_dir}\"")
+endforeach()
+
+list(APPEND CMAKE_REQUIRED_FLAGS -nostartfiles -nostdlib ${isystem_include_flags})
+string(REPLACE ";" " " CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
+
+include(${ZEPHYR_BASE}/cmake/compiler/andes/common.cmake)

cmake/compiler/andes/common.cmake

@@ -0,0 +1,22 @@
+# SPDX-License-Identifier: Apache-2.0
+
+list(TRANSFORM TOOLCHAIN_C_FLAGS REPLACE "^-march=([^ ]+)$" "-march=\\1_xandes")
+list(TRANSFORM TOOLCHAIN_LD_FLAGS REPLACE "^-march=([^ ]+)$" "-march=\\1_xandes")
+list(TRANSFORM LLEXT_APPEND_FLAGS REPLACE "^-march=([^ ]+)$" "-march=\\1_xandes")
+
+if(CONFIG_RISCV_CUSTOM_CSR_ANDES_EXECIT)
+  list(APPEND TOOLCHAIN_C_FLAGS -mexecit)
+  list(APPEND TOOLCHAIN_LD_FLAGS -Wl,--mexecit)
+
+  if(CONFIG_RISCV_CUSTOM_CSR_ANDES_NEXECIT)
+    list(APPEND TOOLCHAIN_LD_FLAGS -Wl,--mnexecitop)
+  endif()
+else()
+  # Disable execit explicitly, as -Os enables it by default.
+  list(APPEND TOOLCHAIN_C_FLAGS -mno-execit)
+  list(APPEND TOOLCHAIN_LD_FLAGS -Wl,--mno-execit)
+endif()
+
+if(CONFIG_RISCV_CUSTOM_CSR_ANDES_HWDSP)
+  list(APPEND TOOLCHAIN_C_FLAGS -mext-dsp)
+endif()

cmake/compiler/andes/compiler_flags.cmake

@@ -0,0 +1,3 @@
+# SPDX-License-Identifier: Apache-2.0
+
+include(${ZEPHYR_BASE}/cmake/compiler/gcc/compiler_flags.cmake)

cmake/compiler/andes/generic.cmake

@@ -0,0 +1,3 @@
+# SPDX-License-Identifier: Apache-2.0
+
+include(${ZEPHYR_BASE}/cmake/compiler/gcc/generic.cmake)

cmake/compiler/andes/target.cmake

@@ -0,0 +1,5 @@
+# SPDX-License-Identifier: Apache-2.0
+
+include(${ZEPHYR_BASE}/cmake/compiler/gcc/target.cmake)
+
+include(${ZEPHYR_BASE}/cmake/compiler/andes/common.cmake)

soc/andestech/ae350/CMakeLists.txt

@@ -13,17 +13,6 @@ zephyr_linker_sources(ROM_START SORT_KEY 0x0 common_linker/init.ld)
 zephyr_linker_sources_ifdef(CONFIG_SOC_ANDES_V5_EXECIT RODATA SORT_KEY 0x0 common_linker/execit.ld)
 zephyr_linker_sources_ifdef(CONFIG_XIP RAM_SECTIONS SORT_KEY 0x0 common_linker/ram_start_nonzero.ld)
 
-# Note: AndeStar V5 DSP needs custom Andes V5 toolchain
-if(CONFIG_SOC_ANDES_V5_HWDSP)
-  zephyr_cc_option(-mext-dsp)
-endif()
-
-# Note: AndeStar V5 EXEC.IT needs custom Andes V5 toolchain
-if(CONFIG_SOC_ANDES_V5_EXECIT)
-  zephyr_cc_option(-mexecit)
-  zephyr_ld_options(-Wl,--mexecit)
-endif()
-
 if(CONFIG_SOC_SERIES_ANDES_AE350)
   set(SOC_LINKER_SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/linker.ld CACHE INTERNAL "")
 endif()

soc/telink/tlsr/tlsr951x/CMakeLists.txt

@@ -13,7 +13,6 @@ zephyr_include_directories(.)
 zephyr_ld_options(-fuse-ld=bfd)
 
 # Set compile options
-zephyr_compile_options_ifdef(CONFIG_TELINK_B91_HWDSP -mext-dsp)
 zephyr_compile_options_ifndef(CONFIG_RISCV_GP -mno-relax)
 zephyr_linker_sources(ROM_START SORT_KEY 0x0 init.ld)