Acceptance test: override immutable bit with transformer

Added acceptance test to test that the trasformer attribute of the files
promise can override the immutable bit of the destination file.

Ticket: ENT-10961, CFE-1840
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_11.cf

@@ -0,0 +1,92 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using transformer
+# attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_11.txt"
+      create => "true";
+
+  commands:
+    "chattr +i /tmp/immutable_11.txt"
+      contain => in_shell;
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the transformer attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  vars:
+    "gzip_path"
+      string => ifelse(
+        isexecutable("/bin/gzip"),
+        "/bin/gzip",
+        "/usr/bin/gzip"
+      );
+
+  files:
+    "/tmp/immutable_11.txt"
+      fsattrs => set_immutable,
+      transformer => "$(gzip_path) $(this.promiser)";
+
+}
+
+bundle agent check
+{
+  classes:
+    "original_exists"
+      expression => fileexists("/tmp/immutable_11.txt");
+    "transformed_exists"
+      expression => fileexists("/tmp/immutable_11.txt.gz");
+    "ok"
+      expression => "!original_exists&transformed_exists";
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "Expected file '/tmp/immutable_11.txt' to not exists $(with)"
+        with => ifelse("!original_exists", "and it does not", "but it does");
+      "Expected file '/tmp/immutable_11.txt.gz' to exists $(with)"
+        with => ifelse("transformed_exists", "and it does", "but it does not");
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_11.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_11.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+  files:
+    "/tmp/immutable_11.txt.gz"
+      delete => tidy;
+}