Acceptance test: override immutable bit with acl

Added acceptance test to test that the acl attribute of the files
promise can override the immutable bit of the destination file.

I'm getting errors stating that acl_get_file is not supported. Maybe
something with WSL? Will retry when I'm back in office.

```
error: No Access ACL for '/tmp/immutable_10.txt' could be read. (acl_get_file: Operation not supported)
```

Ticket: ENT-10961, CFE-1840
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_10.cf

@@ -0,0 +1,99 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using acl attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+body acl acl_user_root_rw
+{
+  acl_method => "append";
+  aces => { "user:root:rw" };
+}
+
+body acl acl_user_root_rwx
+{
+  acl_method => "append";
+  aces => { "user:root:rwx" };
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_10.txt"
+      create => "true",
+      acl => acl_user_root_rw;
+
+  commands:
+    "chattr +i /tmp/immutable_10.txt"
+      contain => in_shell;
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the acl attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  files:
+    "/tmp/immutable_10.txt"
+      fsattrs => set_immutable,
+      acl => acl_user_root_rwx;
+
+}
+
+bundle agent check
+{
+  vars:
+    "getfacl"
+      string => ifelse(
+        fileexists("/var/cfengine/bin/getfacl"), # if
+        "/var/cfengine/bin/getfacl", # then
+        "/usr/bin/getfacl" # else
+      );
+
+    "expected"
+      string => ".*user:root:rwx.*";
+    "actual"
+      string => execresult("$(getfacl) /tmp/immutable_10.txt", "noshell");
+
+  classes:
+    "ok"
+      expression => regcmp("$(expected)", "$(actual)");
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "Expecting ouput matching '$(expected)', got '$(actual)'";
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_10.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_10.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+}