add multiple PCA9685 example

Author: timhendriks93

examples/AdafruitPCA9685/AdafruitPCA9685.ino

@@ -19,7 +19,7 @@ using namespace BlenderServoAnimation;
 // Total animation frames - see original Blender animation / ik.h
 #define FRAMES 100
 
-// Servo object to send positions
+// PWM driver instance to set PWM output
 Adafruit_PWMServoDriver pwm = Adafruit_PWMServoDriver();
 
 // Callback function which is called whenever a servo needs to be moved

examples/MultiplePCA9685/MultiplePCA9685.ino

@@ -0,0 +1,91 @@
+/*
+  Using a struct to map Servos to a PWM driver and channel.
+
+  This approach can be useful if you don't want to equate the servo ID with the
+  PWM board channel or use multiple PCA9685 boards. The Adafruit PCA9685 PWM
+  Servo Driver Library is used to send the servo positions.
+*/
+
+#include "ik.h"
+#include <Adafruit_PWMServoDriver.h>
+#include <BlenderServoAnimation.h>
+
+// Using the namespace to have short class references (Animation and Servo)
+using namespace BlenderServoAnimation;
+
+// Frames per second - see original Blender animation / ik.h
+#define FPS 30
+
+// Total animation frames - see original Blender animation / ik.h
+#define FRAMES 100
+
+// PWM driver instances to set PWM output
+Adafruit_PWMServoDriver pwmA(0x40);
+Adafruit_PWMServoDriver pwmB(0x41);
+
+// Animation object to represent the original Blender animation
+Animation animation(FPS, FRAMES);
+
+// We use a struct to map a servo to a PCA9685 board and channel
+struct servoMap {
+  Servo servo;
+  Adafruit_PWMServoDriver pwm;
+  byte channel;
+};
+
+// Forward declare the callback as it will be referenced in the following array
+void setPWM(byte servoID, int position);
+
+// Define an array of servo maps
+servoMap servoMaps[] = {
+    // Servo attached to board A on channel 0
+    {Servo(0, NeckLeft, setPWM), pwmA, 0},
+
+    // Servo attached to board A on channel 0
+    {Servo(1, NeckRight, setPWM), pwmB, 0},
+};
+
+// Calculate the amount of servos so that we can easily extend the array
+const byte servoAmount = sizeof(servoMaps) / sizeof(servoMaps[0]);
+
+// Callback function which is called whenever a servo needs to be moved
+void setPWM(byte servoID, int position) {
+  // Iterate through the available servos
+  for (int i = 0; i < servoAmount; i++) {
+    // Check if the current servo ID matches the target servo ID
+    if (servoMaps[i].servo.getID() == servoID) {
+      // Get the PWM driver instance and channel from the mapping
+      Adafruit_PWMServoDriver pwm = servoMaps[i].pwm;
+      byte channel = servoMaps[i].channel;
+
+      // Set the current position as PWM output
+      pwm.setPWM(channel, 0, position);
+
+      // Break the loop as we already handled the servo movement
+      break;
+    }
+  }
+}
+
+void setup() {
+  // Dynamically add the Blender servo objects to the animation
+  for (int i = 0; i < servoAmount; i++) {
+    animation.addServo(servoMaps[i].servo);
+  }
+
+  // Trigger the animation play mode
+  animation.play();
+
+  // Initialize servo drivers
+  pwmA.begin();
+  pwmA.setPWMFreq(60);
+  pwmB.begin();
+  pwmB.setPWMFreq(60);
+
+  delay(10);
+}
+
+void loop() {
+  // Update the animation state on each loop
+  animation.run();
+}

examples/MultiplePCA9685/ik.h

@@ -0,0 +1,24 @@
+/*
+  Blender Servo Animation Positions
+
+  FPS: 30
+  Frames: 100
+  Seconds: 3
+  Bones: 2
+  Armature: Armature
+  File: ik.blend
+*/
+
+#include <Arduino.h>
+
+// Servo ID: 0
+const int NeckLeft[100] PROGMEM = {
+  375, 376, 377, 380, 384, 387, 391, 396, 400, 403, 406, 408, 410, 410, 409, 406, 402, 396, 390, 382, 373, 364, 355, 346, 338, 330, 323, 318, 314, 311, 309, 307, 305, 305, 305, 305, 306, 307, 309, 311, 314, 317, 320, 323, 327, 331, 335, 339, 343, 347,
+  351, 356, 360, 364, 369, 374, 380, 386, 392, 398, 404, 410, 415, 420, 425, 429, 432, 435, 436, 437, 437, 436, 435, 434, 432, 430, 428, 426, 423, 421, 418, 415, 412, 409, 406, 403, 400, 397, 394, 391, 388, 386, 384, 381, 380, 378, 377, 376, 375, 375,
+};
+
+// Servo ID: 1
+const int NeckRight[100] PROGMEM = {
+  375, 376, 379, 383, 388, 394, 401, 409, 417, 426, 434, 443, 450, 457, 463, 468, 471, 472, 471, 469, 466, 462, 457, 452, 447, 441, 437, 432, 428, 424, 420, 416, 411, 407, 402, 398, 394, 389, 384, 380, 375, 370, 366, 361, 356, 352, 347, 342, 337, 333,
+  328, 324, 319, 315, 312, 309, 308, 307, 306, 306, 306, 307, 308, 309, 310, 311, 312, 313, 313, 313, 313, 314, 315, 316, 318, 320, 322, 324, 327, 329, 332, 335, 338, 341, 344, 347, 350, 353, 356, 359, 362, 364, 366, 369, 370, 372, 373, 374, 375, 375,
+};